petersweb-infra/nixos/linux.nix

{
  config,
  username,
  hostname,
  pkgs,
  lib,
  nix-index-database,
  inputs,
  specialArgs,
  ...
}: let
  ddnsPkg = import ./invoke-ddns {inherit pkgs;};

  startSeq = builtins.fromJSON ''"\u001b[7m"''; # Start inverted color
  endSeq = builtins.fromJSON ''"\u001b[27m"''; # End inverted color
  motd = "${startSeq} Welcome to the Peterson Mainframe! Look, touch, but DO NOT LICK. ${endSeq}";

  nixPkgs = specialArgs.nixPkgs;
  ourRustVersion = pkgs.rust-bin.selectLatestNightlyWith (toolchain: toolchain.complete);

  ourRustPlatform = nixPkgs.makeRustPlatform {
    rustc = ourRustVersion;
    cargo = ourRustVersion;
  };

  pullomaticPkg = import ./pullomatic {
    inherit lib pkgs;
    rustPlatform = ourRustPlatform;
    specialArgs = {};
  };

  pullomatic = "${pullomaticPkg}/bin/pullomatic";

in {
  imports = [
    (import ./cloned_repos {inherit pkgs pullomatic lib;})
    (import ./firewall.nix {inherit pkgs;})
    (import ./nginx.nix {inherit pkgs lib config;})
    (import ./system/users.nix {inherit pkgs config lib nix-index-database;})
  ];

  time.timeZone = "America/Anchorage";

  age.secrets = {
    nearlyfreespeech = {
      file = ./secrets/nearlyfreespeech.age;
      owner = "root";
    };

    webdav = {
      file = ./secrets/webdav.age;
      owner = "root";
    };

    anthropic-api-key = {
      file = ./secrets/anthropic-api-key.age;
      owner = "root";
    };

    postmark = {
      file = ./secrets/postmark.age;
      owner = "root";
    };

    forgejo-runner-token = {
      file = ./secrets/forgejo-runner-token.age;
      owner = "root";
    };
  };

  environment.systemPackages = [
    ddnsPkg
    pullomaticPkg
    pkgs.vim
    pkgs.php
    pkgs.rustc
    pkgs.cargo
    pkgs.util-linux
    pkgs.iotop
    pkgs.rust-bin.stable.latest.default
    pkgs.wget
    pkgs.tmux

    pkgs.unstable.claude-code

  ];

  swapDevices = [
    {
      device = "/swapfile";
      size = 1 * 1024; # 1GB
    }
  ];

  virtualisation.arion = {
    backend = "docker";
    projects.forgejo.settings = import ./arion/arion-compose.nix;
    projects.riverside.settings = import ./arion-riverside/arion-compose.nix;
  };

  services.gitea-actions-runner.instances."ubuntu" = {
    enable = true;
    name = "ubuntu";
    url = "http://localhost:3000";
    tokenFile = config.age.secrets.forgejo-runner-token.path;
    labels = [
      "ubuntu-latest:host"
      "ubuntu-22.04:host"
      "ubuntu-20.04:host"
    ];
  };

  users.users.gitea-runner = {
    isSystemUser = true;
    group = "gitea-runner";
    extraGroups = [ "docker" ];
    home = "/var/lib/gitea-runner";
    createHome = true;
  };
  users.groups.gitea-runner = {};

  systemd.services.gitea-runner-ubuntu = {
    environment.PATH = lib.mkForce (
      "${pkgs.docker}/bin:${pkgs.git}/bin:${pkgs.nodejs}/bin:/run/current-system/sw/bin:/run/wrappers/bin"
    );
    serviceConfig = {
      DynamicUser = lib.mkForce false;
      User = lib.mkForce "gitea-runner";
      Group = lib.mkForce "gitea-runner";
    };
  };

  systemd.tmpfiles.rules = [
    "d /home/ironmagma/.config 0755 ${username} users"
    "d /root/.config 0755 ${username} users"
    "d /var/riverside/files 0755 root root"
    "d /var/riverside/postgres 0755 root root"
    "d /var/lib/gitea-runner/ubuntu 0755 gitea-runner gitea-runner"
  ];

  networking.hostName = "${hostname}";

  # FIXME: change your shell here if you don't want zsh
  programs.zsh.enable = true;
  programs.zsh.shellInit = ''
    export ANTHROPIC_API_KEY=$(cat ${config.age.secrets.anthropic-api-key.path})
  '';
  environment.pathsToLink = ["/share/zsh"];
  environment.shells = [pkgs.zsh];

  environment.enableAllTerminfo = true;

  security.sudo.wheelNeedsPassword = false;

  users.motd = motd;

  system.stateVersion = "22.05";

  virtualisation.docker = {
    enable = true;
    enableOnBoot = true;
    autoPrune.enable = true;
  };

  # Arion works with Docker, but for NixOS-based containers, you need Podman
  # since NixOS 21.05.
  virtualisation.podman = {
    enable = true;
    defaultNetwork.settings.dns_enabled = true;
  };

  virtualisation.oci-containers = {
    backend = "docker";

    containers = {
      # Example:
      # "hello" = {
      #   autoStart = true;
      #   image = "nginxdemos/hello";
      #   #user = "root:jellyfin";
      #   volumes = [
      #   ];
      #   ports = ["8081:80"];
      # };

      "navidrome" = {
        autoStart = true;
        environment = {
          "TZ" = "America/Anchorage";
          "PUID" = "1000";
          "PGID" = "100";

          "ND_SCANSCHEDULE" = "1h";
          "ND_LOGLEVEL" = "info";
          "ND_SESSIONTIMEOUT" = "24h";
          "ND_BASEURL" = "";
        };
        ports = ["4533:4533"];
        volumes = [
          "/var/navidrome/data:/data"
          "/var/navidrome/music:/music:ro"
        ];
        image = "deluan/navidrome";
      };

      "nextcloud" = {
        autoStart = true;
        image = "quineglobal/ubuntu-with-ssh@sha256:64210887d48fae65bc4552503bf2d21a750ba0417ada530fd31254a8cc916746";
        # image = "nextcloud/28-apache@sha256:ed95d344718ec86df96886b4b3465a9ce553c08b44b47306d399f0f201b04cb3";
        volumes = [ ];
        environment = { };
        ports = ["8087:80"];
      };

      # "ubuntu" = {
      #   autoStart = true;
      #   image = "quineglobal/ubuntu-with-ssh@sha256:64210887d48fae65bc4552503bf2d21a750ba0417ada530fd31254a8cc916746";
      #   volumes = [ ];
      #   environment = {};
      #   ports = ["222:22"];
      # };

      "sync.io" = {
        autoStart = true;
        image = "quineglobal/sync.io@sha256:cbb180301fde42d8d22c26c952a4d4a487469d6491465302d8d79ebf194813b3";
        volumes = [
          "/var/syncio-cache:/sync.io-cache"
        ];
        environment = {};
        ports = ["9090:8080"];
        user = "0"; # run as root
      };
      
      "blog-quine" = {
        autoStart = true;
        image = "quineglobal/blog-quine@sha256:3c2901f772c322d81f843c04d6982b9f50ff0b46d3cc457d9f868a7ff5a15497";
        volumes = [];
        environment = {};
        ports = ["3010:8080"];
      };

      "coldairnetworks" = {
        autoStart = true;
        image = "quineglobal/coldairnetworks-com:latest";
        volumes = [];
        environment = {
		POSTMARK_SERVER_TOKEN = "e718a146-c590-4550-a750-a3b925056e29";
        };
        environmentFiles = [ config.age.secrets.postmark.path ];
        ports = ["3012:8081"];
      };

    };
  };

  nix = {
    settings = {
      trusted-users = [username];

      accept-flake-config = true;
      auto-optimise-store = true;
    };

    registry = {
      nixpkgs = {
        flake = inputs.nixpkgs;
      };
    };

    nixPath = [
      "nixpkgs=${inputs.nixpkgs.outPath}"
      "nixos-config=/etc/nixos/configuration.nix"
      "/nix/var/nix/profiles/per-user/root/channels"
    ];

    package = pkgs.nixVersions.stable;
    extraOptions = ''experimental-features = nix-command flakes'';

    gc = {
      automatic = true;
      options = "--delete-older-than 7d";
    };
  };

  # HTTPS

  security.acme = {
    acceptTerms = true;
    defaults.email = "peterson@sent.com";
    certs."philippeterson.com" = {
      dnsProvider = "nearlyfreespeech";
      environmentFile = config.age.secrets."nearlyfreespeech".path;
      webroot = null;
    };

    certs."webdav.philippeterson.com" = {
      dnsProvider = "nearlyfreespeech";
      environmentFile = config.age.secrets."nearlyfreespeech".path;
      webroot = null;
    };
  };
}